public class AsteroidHandler {
  private Vector roids;
  // Large, Medium, Small 'roids...
  //  private int startNoRoids, noMRoids, noSRoids;
  private int totNoRoids, startNoRoids;
  private int roidSize = 70;
  private final int maxNoIterations = 3;

  /** Creates the large start asteroids.*/
  public AsteroidHandler(int initNoOfRoids) {
    startNoRoids = totNoRoids = initNoOfRoids;    
    roids = new Vector(startNoRoids);
    for(int i=0; i<startNoRoids; i++) {
      roids.add(new Roid(roidSize));
    }
  }

  public void renderRoids() {
    Roid theRoid;
    //println("roidhHandler: totNoRoids="+totNoRoids);
    for(int i=0; i<totNoRoids; i++) {
      theRoid = (Roid) roids.elementAt(i);
      theRoid.move(roidHandler);
      theRoid.render();
    }
  }
  
  /*
  Check if a passed coordinate is within an existing asteroid
  @param x,y coordinates
  @param checkRadius include this area outside of each asteroid in the check
  @return the asteroid corresponding to passed coords, or
  null if coords not within an asteroid */
  public Roid whichRoid(float x, float y, float checkRadius) {
    Roid retRoid = null;
    Roid tmpRoid;
    float crh = checkRadius / 2;
    for(int i=0; i<totNoRoids; i++) {
      tmpRoid = (Roid) roids.elementAt(i);
      float rrh = tmpRoid.r;
      // do the check. this works for rectMode(CENTER)
      if(x>=tmpRoid.x-rrh-crh && x<=tmpRoid.x+rrh+crh)
        if(y>=tmpRoid.y-rrh-crh && y<=tmpRoid.y+rrh+crh) {
          //Coordinate is within an asteroid!
          retRoid = tmpRoid;
        }
    }

    return retRoid;
  }


  // Splits a larger asteroid into two smaller asteroids
  public void splitRoid(Roid inRoid, float hitAngle) {
    Roid theRoid;
    for(int i=0; i<totNoRoids; i++) {
      theRoid = (Roid) roids.elementAt(i);
      if(inRoid.equals(theRoid)) {

        theRoid.iterate();
        if(theRoid.getIteration()>maxNoIterations) {        
          // Delete Roid.
          roids.remove(i);
          totNoRoids--;
        }

        else {
          // Make a copy of the Roid:
          Roid newCell;
          newCell = (Roid) theRoid.clone();        
          newCell.makeSpace();
          newCell.push(hitAngle+PI/2);
          theRoid.push(hitAngle-PI/2);
          roids.insertElementAt(newCell, i);
          totNoRoids++;
          break; // out of the for loop.
        }
      }
    }
  }
  
  public int getNoRoids() {
    return totNoRoids;
  }
  
  // debug function
  public void printVelocities() {
    println("ROID SPEEDS");
    for(int i=0; i<totNoRoids; i++) {
      Roid roid = (Roid) roids.elementAt(i);
      println(i+": xv="+roid.getXv() + "\t\t yv="+roid.getYv() );
    }
    println("=======================");
  }

}